MCS51　算术运算程序（ASM）--匠人的百宝箱

  《匠人手记》推荐网上购书渠道：
互动出版网（china-pub）购书入口   >>>
当当网（dangdang）购书入口   >>>
卓越亚马逊网购书入口   >>>
淘宝网（taobao）购书入口   >>>
更多购书渠道……   >>>

设为首页｜加入收藏｜联系匠人｜管理入口｜21IC首页｜21IC博客｜21IC社区｜侃单片机｜回复的贴｜参与的贴

[加入团队] [加入Q群] [广告赞助] [交换连接] [代理工具] [免责声明]      匠人的原创栏目：[匠人公告] [匠人文集] [匠人笔记] [写书近况]

天气预报

百宝日历

载入中...

百宝专栏

载入中...

最新货色

载入中...

粉丝评论

载入中...

载入中...

百宝信息

载入中...

百宝流量

（2006-07-01开始）

匠人手记

匠人学习：对PIC芯片ROM中的程序地址精确定位

匠人手记网络版：从零开始玩转PIC 之旋转时钟

匠人观点： 好记性不如烂笔头

程序宝典：实用c程序、PIC软件串行口实现技巧

设计技巧：如何阅读别人的代码（目录）

连载专题：程序规划方法漫谈(连载)

用“硬盘音圈电机+三星9454芯片”做的摇摆相框

网络酷文：一个有趣的关于C宏的题目及巧解

黑色幽默：三鹿门——后世畅想

匠人手记：购书攻略、勘误表、书友会、书友Q群

匠人手记：《匠人手记》重印完成，新版照片

MCS51 算术运算程序（ASM）
程序匠人发表于 2005-6-2 0:19:00 阅读全文 | 回复(0) | 引用通告 | 编辑

;双字节取补程序 /(R3R4)=(R3R4)
;入口    :R3,R4
;占用资源:ACC
;堆栈需求:2字节
;出口    :R3,R4

CMPT     :MOV    A,R4
          CPL    A
          ADD    A,#01H
          MOV    R4,A
          MOV    A,R3
          CPL    A
          ADDC   A,#00H
          MOV    R3,A
          RET

;N节取补程序 /([R0])=([R0])
;入口    :R0,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R0

NCMPTN   :MOV    B,R0
          SETB   C
NCPT1    :MOV    A,@R0
          CPL    A
          ADDC   A,#00H
          MOV    @R0,A
          INC    R0
          DJNZ   R7,NCPT1
          MOV    R0,B
          RET

;双字节无符号数加法程序 (R3R4+R6R7)=(R3R4)
;入口    :R3,R4,R6,R7
;占用资源:ACC
;堆栈需求:2字节
;出口    :R3,R4,CF

NADD     :MOV    A,R4
          ADD    A,R7
          MOV    R4,A
          MOV    A,R3
          ADDC   A,R6
          MOV    R3,A
          RET

;N字节无符号数加法程序 ([R0]+[R1])=([R0])
;入口    :R0,R1,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R0,CF

NADDN    :MOV    B,R0
          CLR    C
NADN1    :MOV    A,@R0
          ADDC   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NADN1
          MOV    R0,B
          RET

;双字节无符号数减法程序 (R3R4-R6R7)=(R3R4)
;入口    :R3,R4,R6,R7
;占用资源:ACC
;堆栈需求:2字节
;出口    :R3,R4

NSUB     :MOV    A,R4
          CLR    C
          SUBB   A,R7
          MOV    R4,A
          MOV    A,R3
          SUBB   A,R6
          MOV    R3,A
          RET

;N字节无符号数减法程序 ([R0]-[R1])=([R0])
;入口    :R0,R1,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R0,CF

NSUBN    :MOV    B,R0
          MOV    R7,N
          CLR    C
NSUBN1   :MOV    A,@R0
          SUBB   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NSUBN1
          MOV    R0,B
          RET

;单字节无符号数乘法程序 (R3R4*R7)=(R2R3R4)
;入口    :R3,R4,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R2,R3,R4

NMUL21   :MOV    A,R4
          MOV    B,R7
          MUL    AB
          MOV    R4,A
          MOV    A,B
          XCH    A,R3
          MOV    B,R7
          MUL    AB
          ADD    A,R3
          MOV    R3,A
          CLR    A
          ADDC   A,B
          MOV    R2,A
          CLR    OV
          RET

;单字节无符号数乘法程序 (R2R3R4*R7)=(R5R2R3R4)
;入口    :R2,R3,R4,R6,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R5,R2,R3,R4

NMUL31   :MOV    A,R4
          MOV    B,R7
          MUL    AB
          MOV    R4,A
          MOV    A,B
          XCH    A,R3
          MOV    B,R7
          MUL    AB
          ADD    A,R3
          MOV    R3,A
          CLR    A
          ADDC   A,B
          XCH    A,R2
          MOV    B,R7
          MUL    AB
          ADD    A,R2
          MOV    R2,A
          CLR    A
          ADDC   A,B
          MOV    R5,A
          CLR    OV
          RET

;单字节无符号数乘法程序 (R5R2R3R4*R7)=(R7R5R2R3R4)
;入口    :R5,R2,R3,R4,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R7,R5,R2,R3,R4

NMUL41   :MOV    A,R4
          MOV    B,R7
          MUL    AB
          MOV    R4,A
          MOV    A,B
          XCH    A,R3
          MOV    B,R7
          MUL    AB
          ADD    A,R3
          MOV    R3,A
          CLR    A
          ADDC   A,B
          XCH    A,R2
          MOV    B,R7
          MUL    AB
          ADD    A,R2
          MOV    R2,A
          CLR    A
          ADDC   A,B
          XCH    A,R5
          MOV    B,R7
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          CLR    A
          ADDC   A,B
          MOV    R7,A
          CLR    OV
          RET

;双字节无符号数乘法程序 (R3R4*R6R7)=(R5R2R3R4)
;入口    :R3,R4,R6,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R5,R2,R3,R4

NMUL22   :MOV    A,R4
          MOV    B,R7
          MUL    AB
          XCH    A,R4
          MOV    R5,B
          MOV    B,R6
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          CLR    A
          ADDC   A,B
          MOV    R2,A
          MOV    A,R3
          MOV    B,R7
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          MOV    A,B
          ADDC   A,R2
          MOV    R2,A
          CLR    A
          ADDC   A,#00H
          XCH    A,R3
          MOV    B,R6
          MUL    AB
          ADD    A,R2
          MOV    R2,A
          MOV    A,B
          ADDC   A,R3
          XCH    A,R5
          MOV    R3,A
          CLR    OV
          RET

;双字节无符号数乘法程序 (R2R3R4*R6R7)=(R1R5R2R3R4)
;入口    :R2,R3,R4,R6,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R1,R5,R2,R3,R4

NMUL32   :MOV    A,R4
          MOV    B,R7
          MUL    AB
          XCH    A,R4
          MOV    R5,B
          MOV    B,R6
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          CLR    A
          ADDC   A,B
          MOV    R1,A
          MOV    A,R3
          MOV    B,R7
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          MOV    A,B
          ADDC   A,R1
          MOV    R1,A
          CLR    A
          ADDC   A,#00H
          XCH    A,R3
          MOV    B,R6
          MUL    AB
          ADD    A,R1
          MOV    R1,A
          MOV    A,B
          ADDC   A,R3
          XCH    A,R5
          MOV    R3,A
          MOV    A,R2
          MOV    B,R7
          MUL    AB
          ADD    A,R1
          MOV    R1,A
          MOV    A,B
          ADDC   A,R5
          MOV    R5,A
          CLR    A
          ADDC   A,#00H
          XCH    A,R2
          MOV    B,R6
          MUL    AB
          ADD    A,R5
          MOV    R5,A
          MOV    A,B
          ADDC   A,R2
          XCH    A,R1
          MOV    R2,A
          CLR    OV
          RET

;N字节无符号数乘法程序 ([R0]*[R1])=([R0])
;入口    :R0,R1,M,N
;占用资源:ACC,B,R2,R5,R6,R7,NCNT
;堆栈需求:2字节
;出口    :R0

NMULMN   :MOV    A,M
          ADD    A,R0
          MOV    R5,A
          XCH    A,R1
          XCH    A,R5
          ADD    A,N
          XCH    A,R0
          MOV    R6,A
          MOV    B,M
          MOV    NCNT,B
NMLMN1   :DEC    R0
          DEC    R1
          CLR    A
          XCH    A,@R1
          MOV    @R0,A
          DJNZ   NCNT,NMLMN1
          MOV    NCNT,B
NMLMN2   :CLR    A
          XCH    A,@R0
          MOV    R2,A
          MOV    A,R6
          MOV    R0,A
          MOV    A,R5
          MOV    R1,A
          MOV    R7,N
          CLR    C
NMLMN3   :MOV    A,R2
          MOV    B,@R1
          INC    R1
          MUL    AB
          ADDC   A,@R0
          MOV    @R0,A
          INC    R0
          MOV    A,B
          ADDC   A,@R0
          MOV    @R0,A
          DJNZ   R7,NMLMN3
          INC    R0
          INC    R6
          DJNZ   NCNT,NMLMN2
          MOV    A,R0
          CLR    C
          SUBB   A,M
          SUBB   A,N
          MOV    R0,A
          RET

;单字节无符号除法程序 (R2R3R4/R7)=(R2)R3R4 余数R7
;入口    :R2,R3,R4,R7
;占用资源:ACC,B,F0
;堆栈需求:3字节
;出口    :(R2),R3,R4,R7,OV

NDIV31   :MOV    A,R2
          MOV    B,R7
          DIV    AB
          PUSH   A
          MOV    R2,B
          MOV    B,#10H
NDV311   :CLR    C
          MOV    A,R4
          RLC    A
          MOV    R4,A
          MOV    A,R3
          RLC    A
          MOV    R3,A
          MOV    A,R2
          RLC    A
          MOV    R2,A
          MOV    F0,C
          CLR    C
          SUBB   A,R7
          JB     F0,NDV312
          JC     NDV313
NDV312   :MOV    R2,A
          INC    R4
NDV313   :DJNZ   B,NDV311
          POP    A
          CLR    OV
          JZ     NDV314
          SETB   OV
NDV314   :XCH    A,R2
          MOV    R7,A
          RET

;单字节无符号除法程序 (R5R2R3R4/R7)=(R5)R2R3R4 余数R7
;入口    :R2,R3,R4,R7
;占用资源:ACC,B,F0
;堆栈需求:3字节
;出口    :(R5),R2,R3,R4,R7,OV

NDIV41   :MOV    A,R5
          MOV    B,R7
          DIV    AB
          PUSH   A
          MOV    R5,B
          MOV    B,#18H
NDV411   :CLR    C
          MOV    A,R4
          RLC    A
          MOV    R4,A
          MOV    A,R3
          RLC    A
          MOV    R3,A
          MOV    A,R2
          RLC    A
          MOV    R2,A
          MOV    A,R5
          RLC    A
          MOV    R5,A
          MOV    F0,C
          CLR    C
          SUBB   A,R7
          JB     F0,NDV412
          JC     NDV413
NDV412   :MOV    R5,A
          INC    R4
NDV413   :DJNZ   B,NDV411
          POP    A
          CLR    OV
          JZ     NDV414
          SETB   OV
NDV414   :XCH    A,R5
          MOV    R7,A
          RET

;双字节无符号除法程序 (R5R2R3R4/R6R7)=(R2)R3R4 余数R6R7
;入口    :R5,R2,R3,R4,R6,R7
;占用资源:ACC,B,F0
;堆栈需求:4字节
;出口    :(R2),R3,R4,R6,R7,OV

NDIV42   :MOV    A,R1
          PUSH   A
          MOV    B,#00H
NDV421   :MOV    A,R2
          CLR    C
          SUBB   A,R7
          MOV    R1,A
          MOV    A,R5
          SUBB   A,R6
          JC     NDV422
          MOV    R5,A
          MOV    A,R1
          MOV    R2,A
          INC    B
          SJMP   NDV421
NDV422   :PUSH   B
          MOV    B,#10H
NDV423   :CLR    C
          MOV    A,R4
          RLC    A
          MOV    R4,A
          MOV    A,R3
          RLC    A
          MOV    R3,A
          MOV    A,R2
          RLC    A
          MOV    R2,A
          XCH    A,R5
          RLC    A
          XCH    A,R5
          MOV    F0,C
          CLR    C
          SUBB   A,R7
          MOV    R1,A
          MOV    A,R5
          SUBB   A,R6
          JB     F0,NCV424
          JC     NDV425
NCV424   :MOV    R5,A
          MOV    A,R1
          MOV    R2,A
          INC    R4
NDV425   :DJNZ   B,NDV423
          POP    A
          CLR    OV
          JNZ    NDV426
          SETB   OV
NDV426   :XCH    A,R2
          MOV    R7,A
          MOV    A,R5
          MOV    R6,A
          POP    A
          MOV    R1,A
          RET

;N字节无符号除法程序(组合) ([R0]/[R1])=([R0])
;入口    :R0,R1,M,N
;占用资源:ACC,R2,R3,R4,R5,R7,NCNT,F0,NADDN,NSUBBN,NRLCN
;堆栈需求:4字节
;出口    :R0

;NDIVMN   :MOV    A,M
          CLR    C
          SUBB   A,N
          MOV    NCNT,A
          ADD    A,R0
          MOV    R4,A
          XCH    A,R0
          MOV    R3,A
          MOV    A,R1
          MOV    R5,A
          MOV    R2,#00H
NDVMN1   :MOV    R7,N
          LCALL NSUBN
          MOV    A,R5
          MOV    R1,A
          JC     NDVMN2
          INC    R2
          SJMP   NDVMN1
NDVMN2   :MOV    R7,N
          LCALL NADDN
          MOV    A,NCNT
          SWAP   A
          RR     A
          MOV    NCNT,A
NDVMN3   :MOV    A,R3
          MOV    R0,A
          MOV    R7,M
          LCALL NRLCN
          MOV    F0,C
          MOV    A,R4
          MOV    R0,A
          MOV    A,R5
          MOV    R1,A
          MOV    R7,N
          LCALL NSUBN
          JB     F0,NDVMN4
          JC     NDVMN5
NDVMN4   :MOV    A,R3
          MOV    R0,A
          INC    @R0
          SJMP   NDVMN6
NDVMN5   :MOV    A,R5
          MOV    R1,A
          MOV    R7,N
          LCALL NADDN
NDVMN6   :DJNZ   NCNT,NDVMN3
          MOV    A,R4
          MOV    R1,A
          MOV    A,R2
          MOV    @R1,A
          MOV    A,R3
          MOV    R0,A
          RET

;N字节无符号除法程序(集成) ([R0]/R[1])=([R0])
;入口    :R0,R1,M,N
;占用资源:ACC,R2,R3,R4,R5,R7,F0
;堆栈需求:2字节
;出口    :R0

NDIVMN   :MOV    A,M
          CLR    C
          SUBB   A,N
          MOV    B,A
          ADD    A,R0
          MOV    R4,A
          XCH    A,R0
          MOV    R3,A
          MOV    A,R1
          MOV    R5,A
          MOV    R2,#00H
NDVMN1   :MOV    R7,N
          CLR    C
NDVMN2   :MOV    A,@R0
          SUBB   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NDVMN2
          MOV    A,R4
          MOV    R0,A
          MOV    A,R5
          MOV    R1,A
          JC     NDVMN3
          INC    R2
          SJMP   NDVMN1
NDVMN3   :MOV    R7,N
          CLR    C
NDVMN4   :MOV    A,@R0
          ADDC   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NDVMN4
          MOV    A,#08H
          MUL    AB
          MOV    B,A
NDVMN5   :MOV    A,R3
          MOV    R0,A
          MOV    R7,M
          CLR    C
NDVMN6   :MOV    A,@R0
          RLC    A
          MOV    @R0,A
          INC    R0
          DJNZ   R7,NDVMN6
          MOV    F0,C
          MOV    A,R4
          MOV    R0,A
          MOV    A,R5
          MOV    R1,A
          MOV    R7,N
          CLR    C
NDVMN7   :MOV    A,@R0
          SUBB   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NDVMN7
          JB     F0,NDVMNB
          JC     NDVMN8
NDVMNB   :MOV    A,R3
          MOV    R0,A
          INC    @R0
          SJMP   NDVMNA
NDVMN8   :MOV    R7,N
          MOV    A,R4
          MOV    R0,A
          MOV    A,R5
          MOV    R1,A
          CLR    C
NDVMN9   :MOV    A,@R0
          ADDC   A,@R1
          MOV    @R0,A
          INC    R0
          INC    R1
          DJNZ   R7,NDVMN9
NDVMNA   :DJNZ   B,NDVMN5
          MOV    A,M
          CLR    C
          SUBB   A,N
          ADD    A,R3
          MOV    R1,A
          MOV    A,R2
          MOV    @R1,A
          MOV    A,R3
          MOV    R0,A
          RET

;N字节数据左移程序 RLC([R0])=(CF[R0])
;入口    :R0,R7
;占用资源:ACC,B
;堆栈需求:2字节
;出口    :R0,CF

NRLCN    :MOV    B,R0
          CLR    C
NRLN1    :MOV    A,@R0
          RLC    A
          MOV    @R0,A
          INC    R0
          DJNZ   R7,NRLN1
          MOV    R0,B
          RET

;原码有符号双字节减法程序 (R3R4-R6R7)=R3R4
;入口    :R3,R4,R6,R7
;占用资源:ACC,DADD
;堆栈需求:6字节
;出口    :R3,R4,OV

DSUB     :MOV    A,R6
          CPL    ACC.7
          MOV    R6,A
          LCALL DADD
          RET

;原码有符号双字节加法程序 (R3R4+R6R7)=R3R4
;入口    :R3,R4,R6,R7
;占用资源:ACC,SR0,NADD,NSUB,CMPT
;堆栈需求:4字节
;出口    :R3,R4,OV

DADD     :MOV    A,R3
          MOV    C,ACC.7
          MOV    SR0,C
          XRL    A,R6
          MOV    C,ACC.7
          MOV    A,R3
          CLR    ACC.7
          MOV    R3,A
          MOV    A,R6
          CLR    ACC.7
          MOV    R6,A
          JC     DAB2
          LCALL NADD
          MOV    A,R3
          JB     ACC.7,DABE
DAB1     :MOV    C,SR0
          MOV    ACC.7,C
          MOV    R3,A
          CLR    OV
          RET
DABE     :SETB   OV
          RET
DAB2     :LCALL NSUB
          MOV    A,R3
          JNB    ACC.7,DAB1
          LCALL CMPT
          CPL    SR0
          SJMP   DAB1

;原码有符号双字节乘法程序 (R3R4*R6R7)=(R5R2R3R4)
;入口    :R3,R4,R6,R7
;占用资源:ACC,SR0,NMUL22
;堆栈需求:4字节
;出口    :R5,R2,R3,R4

IMUL     :MOV    A,R3
          XRL    A,R6
          MOV    C,ACC.7
          MOV    SR0,C
          MOV    A,R3
          CLR    ACC.7
          MOV    R3,A
          MOV    A,R6
          CLR    ACC.7
          MOV    R6,A
          LCALL NMUL22
          MOV    A,R5
          MOV    C,SR0
          MOV    ACC.7,C
          MOV    R5,A
          RET

;原码有符号双字节除法程序 (R5R2R3R4/R6R7)=(R3R4) 余数(R6R7)
;入口    :R5,R2,R3,R4
;占用资源:ACC,SR0,NDIV42
;堆栈需求:6字节
;出口    :R3,R4,R6,R7,OV

IDIV     :MOV    A,R5
          XRL    A,R6
          MOV    C,ACC.7
          MOV    SR0,C
          MOV    A,R5
          CLR    ACC.7
          MOV    R5,A
          MOV    A,R6
          CLR    ACC.7
          MOV    R6,A
          LCALL NDIV42
          MOV    A,R3
          JB     ACC.7,IDIVE
          JB     OV,IDIVE
          MOV    C,SR0
          MOV    ACC.7,C
          MOV    R3,A
          RET
IDIVE    :SETB   OV
          RET

看《匠人手记》，与匠人同行！北航出版，正在热卖！

上一篇：MCS51 滤波程序（ASM）

下一篇：MCS51 检索查找程序(ASM)

发表评论：

昵称：

密码： (游客无须输入密码)

主页：

标题：

载入中...

芯片专题

器件专题

软件专题

硬件专题

综合专题

项目专题

原创专题

EMC
Freescale
PIC
MSP430
AVR
ARM

器件检测
 LCD LED
按键触摸键
 E2PROM
电池电机
 电阻电容电感

指令系统
 软件算法
 编程规范
 滤波算法
 串行通讯

PCB设计
 I2C PWM
红外遥控
 充电技术
 中断 ADC

新手入门
 项目管理
 电磁兼容
 低功耗

汽车电子
 电子秤
 电磁炉
 电动车
 报警器

匠人手记
 匠人夜话
 网络心路
 一周热点串烧
 从零开始玩PIC
DIY旋转时钟

广告5号位 [投放]

学习板、开发板、编程器、下载器、仿真器（查看详情……）

广告3号位 [投放]

站内搜索

站外搜索

百度 google
mp3 歌词
图片 FLASH
知道文档
新闻词典
地图 mp3
软件天网
雅虎爱问
搜狗讯雷
网讯华军
天空

21IC器件搜索

百宝箱分站

《匠人的百宝箱》21IC站
《匠人的百宝箱》21IC笔记团队
《匠人手记》21IC书友会
《匠人的百宝箱》MCUBLOG站
《匠人的百宝箱》MCUBLOG笔记团队
《匠人的百宝箱》EDN站
《匠人手记》EDN书友会
《匠人的百宝箱》与非网站
《匠人的百宝箱》新浪站
《匠人的百宝箱》百度站
《匠人的百宝箱》网易126站
《匠人的百宝箱》网易163站
《匠人的百宝箱》互动出版网站

广告4号位 [投放]

匠人原创

往日酷贴

心灵的震撼——写在512地震之后、《戒色》新片发布会(网友聚会恶搞系列)、

两粒电子的爱情、出书的那些日子……、论21ic的论坛文化、续、性格决定命运、

选狼还是选狮子、狮子的结局…、《匠人夜话》27：七年之痒—写在升任21icbbs站长之际、

匠人自制低成本电容式触控板、《21icbbs人物志》续集、上海街头实景、

一阶滤波算法之深入研究、淘书手记、什么是散转程序、《匠人手记》新书艳照、

EDN《匠人手记》签名售书优惠活动开始报名啦！、欢迎加入《匠人手记》EDN书友会、

欢迎加入《匠人手记》书友会Q群、《匠人手记》终稿目录、《匠人手记》封面先睹为快、

IAR-C-FOR-SAM89(三星)中实现位操作、享受一下VIP的待遇，哈哈、

渐明渐暗动态流水灯效果（C源程序）、《匠人手记》购书全攻略、

《匠人的百宝箱》21IC笔记团队、《匠人手记》义拍活动，得款直接捐献灾区、浅谈A/D、

太阳能应用图片集粹1、Keil C动态内存管理机制分析及改进、一种触摸实现方式、

modelsim仿真UART接收功能、关于射频表无法用红外改写时间的问题、

一定要珍惜的十种人、PADS2007安装问题解决方案、：博客，改变的不仅仅是图书、

C语言宏定义技巧、C语言条件编译详解、21IC上海2008-04聚会报名进行中。。。、

你的博客还能持续多久（转贴）、电动车无刷电机控制器软件设计要点（作者:谢渊斌）、

大千八卦

友情连接

新浪新闻：

新浪财经：

AK58新闻：

新浪股票：

新浪股票：

证券之星：

[更多酷站连接]

[欢迎交换连接]

[百宝箱之与非门分舵]

[电脑圈圈的家当]

[IC921的博客]

[柔月阁]

[八楼的呼吸]

[hotpower 的水潭]

[xwj的文君阁]

[所长的BLOG]

[阿摆手记]

[电子伙伴]

[unaided的笔记]

[小飞的笔记]

[单片机开发联盟]

[网址之家]

[好东西网址大全]

[美萍中文精选]

[数字电视之家]

[SMARTCODE电子书斋]

[软件开发之窗]

[Armoric的笔记]